คำ VBA ว้าบน parentheticals

คุณกำลังพยายามจะตรงกับวงเล็บรอบจำนวนเงินซึ่งอยู่ในคำคืนที่ยากและ thankless งานเป็นคำเดียวที่เห็นการเปิดและปิดวงเล็บรอบจำนวนเงิเป็นปัจเจกบุคคลตัวอักษรและไม่ใช่โดยอัตโนมัติที่เข้าคู่กับคำพูด รหัสทางด้านล่าเจตรงกับวงเล็บรอบจำนวนเงิ,จะช่วยลดอแกะรอยตามช่องว่าง,habdles กรณีของวงเล็บรอบจำนวนเงิไม่เป็นปัจจุบันและเกิดข้อผิดพลาดถ้าคุณต้องคือความไม่สมดุลเกิดข้อผิดพลาด. ฉันทิ้งไว้ในการดีบั๊กการให้สอบสวนดังนั้นคุณสามารถยกเลิกหมายเหตุพวกเขาจะเห็นสิ่งที่กำลังเกิดขึ้น

Option Explicit

Public Sub ttest()

    Dim myRange As Word.Range
    Set myRange = ActiveDocument.StoryRanges(wdMainTextStory)
    myRange.Collapse direction:=wdCollapseStart
    
    
    Set myRange = NextParenRange(myRange)
    
    Do Until myRange Is Nothing
    
        DoEvents
        
        Debug.Print myRange.Text
        Dim myDupRange As Word.Range
        Set myDupRange = myRange.Duplicate
        myRange.Collapse direction:=wdCollapseEnd
        If myDupRange.Characters.Last.Next.Text = " " Then myDupRange.MoveEnd Count:=1
        myDupRange.Delete
        Set myRange = NextParenRange(myRange)
        
    
    Loop
    
End Sub

Public Function NextParenRange(ByVal ipRange As Word.Range) As Word.Range

    Const OpenP As String = "("
    Const CloseP As String = ")"
    
    Dim myRange As Word.Range
    Set myRange = ipRange.Duplicate
    
    'If myRange.Start <> myRange.End Then myRange.Collapse direction:=wdCollapseStart
    
    'exit if no parentheses exist
    'Debug.Print myRange.Start
    If myRange.MoveUntil(cset:=OpenP) = 0 Then
    
        Set NextParenRange = Nothing
        Exit Function
        
        
    Else
    
        'Debug.Print myRange.Start
        Dim myParenCount As Long
        myParenCount = 1
        myRange.MoveEnd Count:=1

    End If
    
    
    Do Until myParenCount = 0
    
        ' allows VBA to respond to a break key press
        DoEvents
        
        ' if we run out of parentheses before we get back to zero then flag an error
        If myRange.MoveEndUntil(cset:=OpenP & CloseP) = 0 Then
        
            VBA.Err.Raise 17, "Unbalanced parentheses in document"
            
            
        End If
        
        myRange.MoveEnd Count:=1
        'Debug.Print myRange.Characters.Last.Text
        'Debug.Print myRange.Characters.Last.Next.Text
        myParenCount = myParenCount + IIf(myRange.Characters.Last.Text = OpenP, 1, -1)
        
    
    Loop
    
    Set NextParenRange = myRange.Duplicate
    
End Function